Formula for "Due" and "Past Due"


#1

I have a table of tasks. Each task has a due date in a date field.

I want to create a new formula field that looks at the due date and spits out:

Upcoming
Due Today
Past Due

Extra credit if the formula can spit out “Due Soon” when a task is 2 days away.

How do I make this happen?


#2

This will accomplish what you requested.

IF (
	{Due}="",
	"Not Set",
	IF(
		AND(
			DATETIME_DIFF({Due},TODAY(),'hours') >= 12,
			DATETIME_DIFF({Due},TODAY(),'hours') <= 48
		),
		"Due Soon",
		IF(
			IS_BEFORE({Due},TODAY()),
			"Past Due",
			IF (
				IS_SAME({Due},TODAY()),
				"Due Today",
				"Upcoming"
			)
		)
	)
)

#3

Wow @Chester_McLaughlin - you nailed it!

I was able to get “upcoming”, “today”, and “past” working on my own, but “soon” was beyond me.

Also you took into account tasks with no due date! I didn’t know that was possible.

I learned a lot just from seeing this formula work. Thank you!


#4

@Chester_McLaughlin how would I modify this so it’s eastern standard time?


#5

I’m starting to get the feeling that there’s more to Airtable than I even understand (like when I read this!). Where would I put that formula??? Sorry to sound so dumb but I’m pretty new at Airtable in general.


#6

Here’s the best place to get familiar with the formula field type.

And here’s a quick glimpse of how to set a field to be of type “formula”


#7

I haven’t tested this, however this should work for your timezone.

if (
	{Due}="",
	"Not Set",
	IF(
		AND(
			DATETIME_DIFF(SET_TIMEZONE({Due},'America/New_York'),SET_TIMEZONE(TODAY(),'America/New_York'),'hours') >= 12,
			DATETIME_DIFF(SET_TIMEZONE({Due},'America/New_York'),SET_TIMEZONE(TODAY(),'America/New_York'),'hours') <= 48
		),
		"Due Soon",
		IF(
			IS_BEFORE(SET_TIMEZONE({Due},'America/New_York'),SET_TIMEZONE(TODAY(),'America/New_York')),
			"Past Due",
			IF (
				IS_SAME(SET_TIMEZONE({Due},'America/New_York'),SET_TIMEZONE(TODAY(),'America/New_York')),
				"Due Today",
				"Upcoming"
			)
		)
	)
)

#8

I’m trying to do this formula, replacing {Due} with my field name {Print Due Date}, but I keep getting an error on the formula.

Here’s my video to show you what I’m doing: http://example.24hrtees.net/kL8J

I’d love some help.


#9

@Chais_Meyer, I had the same problem when I copied and pasted the formula as written by @Chester_McLaughlin.

The layout of the formula is nice because the various IF statements can be identified clearly, along with the corresponding opening and closing parentheses. But, it seems that Airtable has a problem with spaces in the formula. When I removed the spaces, the formula worked fine.


#10

@Chester_McLaughlin Thanks for the code, but i seems to be an error, i replace “Due” with “Deadline” and remove the spaces, but i still have an error in the formula, can you check the code?

Thanks!


#11

You’ve probably already figured this out, but as a breadcrumb for future searchers, it’s the two spaces following IF on lines 1 and 13 causing the problem; there should be no space between ‘IF’ and the opening parenthesis, as so: IF(. The rest of the white space – which, as @Christoff points out, makes the code much easier to read, can stay; Airtable ignores it.


#12

The problem is “”, if you look carefully when you copy from web and past to the airtable, it generate to another character not same with the " understand in airtable. Hope it help you. It took me ages to debug and look carefully.


#13

@Chester_McLaughlin This worked perfectly for me once I deleted the additional spaces. Now I am wondering if I can add one more piece to the formula. This would be based on another Checkbox Column (separate from the Due Column). In other words, if the checkbox column is checked, I want the Report Status to say “Received” instead of “Past Due”. Is that possible?


#14

Certainly. Here’s the basic format for checking the status of a checkbox field:

IF({My Checkbox Field}=TRUE(),"It is checked!!!","It is NOT checked")

And if you ever want to check the inverse, do:

IF({My Checkbox Field}=FALSE(),"It is NOT checked","It is checked!!!")

Or you could do:

IF(NOT({My Checkbox Field},TRUE()),"It is NOT checked","It is checked!!!")


#15

Thanks, @Chester_McLaughlin Chester. I was able to make this work when I made a new column. But
I want to imbed this into the original formula from the thread. Is that
possible? So in one column, there would be either Received, Upcoming, or
Past Due. Upcoming and Past Due are generated from the datetime diff and
Received would be like an override if I select the checkbox in that row.


#16
IF(
	{Received}=TRUE(),
	"Received",
	IF(
		{Deadline}="",
		"Not Set",
		IF(
			AND(
				DATETIME_DIFF(SET_TIMEZONE({Deadline},'America/New_York'),SET_TIMEZONE(TODAY(),'America/New_York'),'hours') >= 12,
				DATETIME_DIFF(SET_TIMEZONE({Deadline},'America/New_York'),SET_TIMEZONE(TODAY(),'America/New_York'),'hours') <= 48
			),
			"Due Soon",
			IF(
				IS_BEFORE(SET_TIMEZONE({Deadline},'America/New_York'),SET_TIMEZONE(TODAY(),'America/New_York')),
				"Past Due",
				IF (
					IS_SAME(SET_TIMEZONE({Deadline},'America/New_York'),SET_TIMEZONE(TODAY(),'America/New_York')),
					"Due Today",
					"Upcoming"
				)
			)
		)
	)
)

#17

@Chester_McLaughlin This did it. Very cool! Thanks a lot.


#19

Looks like I’m about a year late to the party but the code still doesn’t work for me :frowning:
I deleted all spaces and re-typed all "
Any other tips on how I could make this work?


#20

What happens to me a lot when working on formulas is I accidentally delete or forget a a comma and/or a bracket :sweat_smile:.
It may be simply it.

Could you copy/paste here your corrected formula to see if … ? :wink:


#21

IF(Due="",“Not Set”,IF(AND(DATETIME_DIFF(Due,TODAY(),‘hours’)>=12,DATETIME_DIFF(Due,TODAY(),‘hours’)<=48),“Due Soon”,IF(IS_BEFORE(Due,TODAY()),“Past Due”,IF(IS_SAME({Due},TODAY()),“Due Today”,“Upcoming”)