FIND formula to identify one or many issues in a URL

[airballer86]

I am trying to use the find formula to identify one or many issues in a URL

For example in the field Link URL I have two urls; one with one issue and one with multiple issues
https://www.google.com/workin'-late.html
or
http://www.google.com/workin'-late.html

Any help would be appreciated. Here was my first go at it:
IF({Link URL},
IF(FIND("http://", {Link URL}), 'missing https',
IF(FIND("'", {Link URL}), 'remove apostrophe',
IF(
FIND("http://", {Link URL}),
FIND("'", {Link URL})
, 'missing https and remove apostrophe'
)
)
)
)

[Sho]

It's easy if it's a list of words, but when you try to connect them with AND, it becomes difficult!

IF(
  {Link URL},
  IF(
    FIND("http://", {Link URL}),
    IF(
      FIND("'", {Link URL}),
      'missing https and remove apostrophe',
      'missing https'
    ),
    IF(
      FIND("'", {Link URL}),
      'remove apostrophe'
    )
  )
)

If you plan to add more conditions, this could be a better one.

IF(
  {Link URL},
  IF(
    FIND("http://", {Link URL}),
    'missing https, '
  )&
  IF(
    FIND("'", {Link URL}),
    'remove apostrophe, '
  )
)

[airballer86]

@Sho 

Your second option is perfect! One more thing, how would I identify something missing; e.g., the URL starts with www.google..com (missing the https://) 

IF(
  {Link URL},
  IF(
    FIND("http://", {Link URL}),
    'missing https, '
  )&
  IF(
    FIND("'", {Link URL}),
    'remove apostrophe, '
  )&
  IF(
    FIND("NO https://", {Link URL}),
    'missing https, '
  )
)

[airballer86]

@Sho how would I identify something missing; e.g., the URL starts with www.google..com (missing the https://) 

IF(
  {Link URL},
  IF(
    FIND("http://", {Link URL}),
    'missing https, '
  )&
  IF(
    FIND("'", {Link URL}),
    'remove apostrophe, '
  )&
  IF(
    FIND("NO https://", {Link URL}),
    'missing https, '
  )
)

[Sho · Accepted solution]

Sorry, I missed that!

NOT() to determine if it's missing.

IF(
  {Link URL},
  IF(
    OR(
      FIND("http://", {Link URL}),
      NOT(FIND("https://", {Link URL}))
    ),
    "missing https, "
  ) &
  IF(
    FIND("'", {Link URL}),
    'remove apostrophe, '
  )
)