Help

Re: Kanban View by Date

975 0
cancel
Showing results for 
Search instead for 
Did you mean: 
Marianne_Hislop
5 - Automation Enthusiast
5 - Automation Enthusiast

Is there a way to view data in a Kanban view by date, so that it looks more like a calendar of due tasks. The Calendar view is too limited in that it just shows one line and you have to click on each record to see more. As we do not depend on “time”, only dates I would like to have a calendar view with all jobs on a card under the due date etc. Hope this makes sense. It doesn’t seem to allow me to choose the date field.

Thank you

1 Reply 1
pcbowers
6 - Interface Innovator
6 - Interface Innovator

@Marianne_Hislop There are a number of ways that you could do this. One potential option is to create a single select field with various tags containing the date period in which you want to do the task:

image

This would result in a view similar to this:

image

You could also label them Week [0-52] for brevity/clarity. This is one of many options that would allow you to see more task information.

That being said, I would suggest sticking with the calendar and adding the kanban view: have a calendar view that shows the dates, and have a kanban view that shows what is currently being worked on like this:

image

This way, one can differentiate between due dates and project status. Furthermore, I still get the benefit of having a field that is actually typed as a date for any future formulas that I need to use the date information. If you still want some form of time frame on each task, I like to do a relative due date that looks something like this:

image

Based on the colors, I can clearly tell what is coming up (green means I have a month or more, yellow means I’ve got weeks left, orange means a day or so, and red means it’s past due. There are no red one’s in my example). Here is an example formula that you can tweak to your liking:

IF(
    {Status}="Completed",
    "Completed ✅",
    IF(
        DATETIME_DIFF({Due Date}, TODAY(), "years")>0,
        IF(
            DATETIME_DIFF({Due Date}, TODAY(), "years")=1,
            "Due in 1 year 🟢",
            "Due in " & DATETIME_DIFF({Due Date}, TODAY(), "years") & " years 🟢"
        ),
        IF(
            DATETIME_DIFF({Due Date}, TODAY(), "months")>0,
            IF(
                DATETIME_DIFF({Due Date}, TODAY(), "months")=1,
                "Due in 1 month 🟢",
                "Due in " & DATETIME_DIFF({Due Date}, TODAY(), "months") & " months 🟢"
            ),
            IF(
                DATETIME_DIFF({Due Date}, TODAY(), "weeks")>0,
                IF(
                    DATETIME_DIFF({Due Date}, TODAY(), "weeks")=1,
                    "Due in 1 week 🟡",
                    "Due in " & DATETIME_DIFF({Due Date}, TODAY(), "weeks") & " weeks 🟡"
                ),
                IF(
                    DATETIME_DIFF({Due Date}, TODAY(), "days")>0,
                    IF(
                        DATETIME_DIFF({Due Date}, TODAY(), "days")=1,
                        "Due tomorrow 🟠",
                        "Due in " & DATETIME_DIFF({Due Date}, TODAY(), "days") & " days 🟡"
                    ),
                    IF(
                        DATETIME_DIFF({Due Date}, TODAY(), "days")=0,
                        "Due today 🟠",
                        "Past due 🔴"
                    )
                )
            )
        )
    )
)

It relies on a field called Status and Due Date. The first to check if the task is completed, the second to pull the actual due date from and do these relative calculations.

I hope this gives you some ideas!