List of all fields where checkbox is not checked

[Kelly_Vorrasi1]

Hi Folks, 

I've been trying to come up with an elegant solution to this and am hoping the community here can help me. I have several fields of checkboxes marking different assets available in our library. I would love to create a signal field that would list which fields are still unchecked. Is this possible? I've tried a few variations but nothing is working. 

Thanks!

[Ben_Young1 · Accepted solution]

Hey @Kelly_Vorrasi1! 

Here's a fun formula that dynamically summarizes your checkbox fields and provides return values based on what's currently provided:

IF(
    AND(
        {LAS Art}, {BPO Art}, {IT Art}, {JP Art}, {POL Art}, {FR Art}),
    "✅ All Fields Completed",
    IF(
        AND(
            NOT({LAS Art}),
            NOT({BPO Art}),
            NOT({IT Art}),
            NOT({JP Art}),
            NOT({POL Art}),
            NOT({FR Art})
        ),
        "❌ Missing All Fields",
        TRIM(
            "Missing Fields:\n" & 
            IF(
                NOT({LAS Art}),
                "- LAS Art\n"
            )
            &
            IF(
                NOT({BPO Art}),
                "- BPO Art\n"
            )
            &
            IF(
                NOT({IT Art}),
                "- IT Art\n"
            )
            &
            IF(
                NOT({JP Art}),
                "- JP Art\n"
            )
            &
            IF(
                NOT({POL Art}),
                "- POL Art\n"
            )
            &
            IF(
                NOT({FR Art}),
                "- FR Art\n"
            )
        )
    )
)

Here's what it looks like in Airtable:

Everything is pretty cleanly nested so that you can extract any key parts of the formula if you'd like to tweak things around to fit your needs.

Always happy to answer any questions about the formula or how it works.

[Kelly_Vorrasi1]

Wow that works beautifully! Thank you so much! 

[BrCHC]

How would this work if you wanted to list the boxes that WERE checked? I have created a form that matches volunteers with potential jobs depending on their answers to three questions (video attached) and I want a field to be a consolidation of everything they have checked.
Thank you!

Thank you! 😊