Concatenated text field in automation

[Leah_Relish]

I would like to omit the semi-colon when a field is blank, and I know it can be done using IF, however my brain cannot wrap around how to pull it together! Can anyone help?

Here’s my example:

The current Formula I am using:

Much appreciated :slightly_smiling_face:

[kuovonne]

There are several possible formulas. Here is one that assumes that you will always havve a {Manufacturer}

CONCATENATE(
  {Manufacturer},
  IF({Product}, "; " & {Product}),
  IF({Operating System}, "; " & {Operating System}),
  IF({Material}, "; " & {Material}),
  IF({Colour}, "; " & {Colour}),
  IF({Other Details}, "; " & {Other Details})
)

[Leah_Relish]

Thank you! I won’t always have a manufacturer, but I tried your formula and I’m not sure what I am doing wrong:

[kuovonne]

Leah_Relish:

but I tried your formula and I’m not sure what I am doing wrong:

Is the problem that the formula won’t save, or is the problem that the formula gives the wrong result?

Is there a reason why the line breaks in the formula were removed?

[Leah_Relish]

So, I got it to work after retyping it several times! Must have been doing something weird. But I am not able to omit the first ; if Manufacturer is empty.

[kuovonne]

Leah_Relish:

I won’t always have a manufacturer

REGEX_REPLACE(
  CONCATENATE(
    IF({Manufacturer}, {Manufacturer} & "; "),
    IF({Product}, {Product} & "; "),
    IF({Operating System}, {Operating System} & "; "),
    IF({Material}, {Material} & "; "),
    IF({Colour}, {Colour} & "; "),
    IF({Other Details}, {Other Details})
  ),
  "; $",
  ""
)

[Leah_Relish]

You are a genius! Thank you