Help

Upcoming database upgrades. Airtable functionality will be reduced for ~15 minutes at 06:00 UTC on Feb. 4 / 10:00 pm PT on Feb. 3. Learn more here

The formula IF there is something it is supposed to show "✔️" or "❌"

Topic Labels: Formulas
Solved
Jump to Solution
266 2
cancel
Showing results for 
Search instead for 
Did you mean: 

I would like the formula to be able to identify the client by field {Rodzaj usługi}. If the client would be (in the {Rodzaj usługi}) “Fotografia ślubna” then I would like {Status} to show “ :heavy_check_mark: ” only if the {Odbitki}, {Album}, {Galeria internetowa}, {Selekcja zdjęć}, {Zwiastun}, {Obróbka zdjęć} fields will be filled with the word “Oddane”. Otherwise, the {Status} field should show “ :x: ”. When the client would be (in the {Rodzaj usługi}) “Film ślubny” then I would like {Status} to show “ :heavy_check_mark: ” only if the {Film wrzucony na dysk}, {Teledysk ślubny}, fields will be filled with the word “Oddane”. Otherwise, the {Status} field should show “ :x: ”.
image

1 Solution

Accepted Solutions

Welcome to the community, @Bartek !

You’ll want to use a combination of a few functions here.

First, I would use the SWITCH() function to determine the calculation you want to use.

SWITCH({Rodzaj usługi}, "Fotografia ślubna", <<calculation 1>>, "Film ślubny", <<calculation 2>>)

Then, for each calculation, you’ll want to use a combination of IF() and AND() to check each field.

<<calculation 1>> ({Rodzaj usługi} = “Fotografia ślubna”):

IF(AND({Odbitki} = "Oddane", {Album} = "Oddane", {Galeria internetowa} = "Oddane", {Selekcja zdjęć} = "Oddane", {Zwiastun} = "Oddane", {Obróbka zdjęć} = "Oddane"), "✔️", "")

<<calculation 2>> ({Rodzaj usługi} = “Film ślubny”):

IF(AND({Film wrzucony na dysk} = "Oddane", {Teledysk ślubny} = "Oddane"), "✔️", "")

All together:

SWITCH({Rodzaj usługi}, "Fotografia ślubna", IF(AND({Odbitki} = "Oddane", {Album} = "Oddane", {Galeria internetowa} = "Oddane", {Selekcja zdjęć} = "Oddane", {Zwiastun} = "Oddane", {Obróbka zdjęć} = "Oddane"), "✔️", ""), "Film ślubny", IF(AND({Film wrzucony na dysk} = "Oddane", {Teledysk ślubny} = "Oddane"), "✔️", ""))

To take it one step further, you could write it a bit more elegantly by using just one IF() statement…

IF(SWITCH({Rodzaj usługi}, "Fotografia ślubna", AND({Odbitki} = "Oddane", {Album} = "Oddane", {Galeria internetowa} = "Oddane", {Selekcja zdjęć} = "Oddane", {Zwiastun} = "Oddane", {Obróbka zdjęć} = "Oddane"), "Film ślubny", AND({Film wrzucony na dysk} = "Oddane", {Teledysk ślubny} = "Oddane")), "✔️", "")

I hope this helps!

See Solution in Thread

2 Replies 2

Welcome to the community, @Bartek !

You’ll want to use a combination of a few functions here.

First, I would use the SWITCH() function to determine the calculation you want to use.

SWITCH({Rodzaj usługi}, "Fotografia ślubna", <<calculation 1>>, "Film ślubny", <<calculation 2>>)

Then, for each calculation, you’ll want to use a combination of IF() and AND() to check each field.

<<calculation 1>> ({Rodzaj usługi} = “Fotografia ślubna”):

IF(AND({Odbitki} = "Oddane", {Album} = "Oddane", {Galeria internetowa} = "Oddane", {Selekcja zdjęć} = "Oddane", {Zwiastun} = "Oddane", {Obróbka zdjęć} = "Oddane"), "✔️", "")

<<calculation 2>> ({Rodzaj usługi} = “Film ślubny”):

IF(AND({Film wrzucony na dysk} = "Oddane", {Teledysk ślubny} = "Oddane"), "✔️", "")

All together:

SWITCH({Rodzaj usługi}, "Fotografia ślubna", IF(AND({Odbitki} = "Oddane", {Album} = "Oddane", {Galeria internetowa} = "Oddane", {Selekcja zdjęć} = "Oddane", {Zwiastun} = "Oddane", {Obróbka zdjęć} = "Oddane"), "✔️", ""), "Film ślubny", IF(AND({Film wrzucony na dysk} = "Oddane", {Teledysk ślubny} = "Oddane"), "✔️", ""))

To take it one step further, you could write it a bit more elegantly by using just one IF() statement…

IF(SWITCH({Rodzaj usługi}, "Fotografia ślubna", AND({Odbitki} = "Oddane", {Album} = "Oddane", {Galeria internetowa} = "Oddane", {Selekcja zdjęć} = "Oddane", {Zwiastun} = "Oddane", {Obróbka zdjęć} = "Oddane"), "Film ślubny", AND({Film wrzucony na dysk} = "Oddane", {Teledysk ślubny} = "Oddane")), "✔️", "")

I hope this helps!

Thank you sooo much! You are the best :slightly_smiling_face: