In-Cell Progress Bar for Each Record

[Max_Goldberg]

Hi -
We’re looking to pull a percentage of a task complete and reflected that % as a progress bar in a cell for a single record. We want the progress bar to be continuous (up to an integer) as the % of the task completed is updated… I.e. (just one of many use cases) if we have a record that is counting # of forms submitted for a given record, and the total number is noted in the record, the percentage of completed forms with respect to the completed record is reflected in an updating graphic progress bar.

Bootstrap plugin example: https://www.w3schools.com/bootstrap/bootstrap_progressbars.asp.

The progress bar Airtable feature should update from as the percentage cell on the record self-updates upon completion of a given trigger elsewhere in the Airtable ecosystem.

Many thanks!

[Jeff_Haskin]

Alternatively, here’s a easy one using a “Progress” field and a “Progress Bar” field:

CONCATENATE(
  REPT("█",(({Progress}*100)/5)-MOD({Progress}*100,5)/5),
  REPT("░",20-((({Progress}*100)/5)-MOD({Progress}*100,5)/5))
)

Each black square represents 5% progress. Gray squares show the total possible progress.

[Jeff_Haskin]

Here ya go!

CONCATENATE(
  CONCATENATE(
    REPT(" ",(3-LEN(CONCATENATE(ROUND({Total Task Progress}*100,0))))*2),
    CONCATENATE(ROUND({Total Task Progress}*100,0)),
    "%  "
    ),
  CONCATENATE(
    REPT(
      IF({Total Task Progress}<0.20,"🟥",
        IF({Total Task Progress}<0.40,"🟧",
          IF({Total Task Progress}<0.60,"🟨",
            IF({Total Task Progress}<0.80,"🟦",
              IF({Total Task Progress}<1.00,"🟩","")
            )
          )
        )
      ),
    (({Total Task Progress}*100)/10)-MOD({Total Task Progress}*100,10)/10),
    REPT("⬜",10-((({Total Task Progress}*100)/10)-MOD({Total Task Progress}*100,10)/10))
  )
)

[Jeff_Haskin]

The benefit to having the progress percentage itself appear in its own column next to the progress bar (rather than appearing with the progress bar) is that when you have groupings and the progress percentage field is showing, you can have percent values total up across groups, which doesn’t work when it’s merely displayed with the progress bar in the same field.

[gliddon]

This is an awesome formula, thanks so much! The only issue I have is that the 100% doesn’t display the pretty emoji progress bar you made. Here’s what I see:

I use a linked record for Status, then assigned each Status a % Progress score. Then I look up that % score as the Total Task Progress in your formula above.

Any suggestions as to how to get that 100% all green bar looking right? I’ll keep fiddling, but thought I’d ask anyways!

[Hewitt]

@gliddon in your last if statement IF statement add an additional green box where the blank is. This should allow the 100% bar to appear

IF({Calculation}<1.00,“ :green_square: ”,“ :green_square: ”)

Also, how did you get rid of the spacing between your squares?

[Roxane_Uzureau]

You guys are mind-blowing… i spend HOURS trying to work what the best LAYOUT is on my airtables!
Ok, so I have yet another layer of complexity to add here:
I want the progress bar to update according to the amount of tasks completed (already calculated from two other Lookup cells to get the relevant info from TASKS tab)
I have a box already for the numbers of tasks complete :slightly_smiling_face:

Can anyone help on how would I go about that?

[G_T]

This was an excellent thread! Thank you for the formulas.

I wanted to comment with a slightly updated version.

I took the progress bar from above and altered it via these items:

• made a version that has a continuous progress bar (no boxes or squares)
• made a version that is small for mobile devices

Plus, I added a component, to show how many tasks for a project are in the following status. I spaced them out so they always appear on the left, in the middle, or on the right;

• To Do - shown via this symbol ⎋
• Waiting (on someone) - shown via this symbol ⏎
• In Progress - shown via this symbol ➤

[G_T]

The graphic comes from these fields
Combination Field

CompletionBar&'\n'&{Status graphic}

CompletionBar field
(this is the same formula from above, but I replaced the square progress indicators with different ones, called Full Width within Apple Emoji keyboard. The full width aspect lets them touch, appearing as if it is a continuous indicator, instead of boxes lined up in a row

IF(
    PercentDone >= 0,
    REPT(
        '▅',
        ROUND( MIN(PercentDone, 1) * 10 )
    )
    &
    REPT(
        '﹏',
        10 - ROUND( MIN(PercentDone, 1) * 10)
    )
    &
    ' '
    &
    INT( MIN(PercentDone, 1) * 100 )
    &
    '%'
)

Status Graphic field

IF({rollupDONE matches percent done}="✔️Confirmed Done","☑️Done",CONCATENATE(
  IF(
    AND({⎋count To Do}>0,{⎋count To Do}<10),
    "⎋"&{⎋count To Do}&"               ",
    IF(
      {⎋count To Do}>=10,
      "⎋"&{⎋count To Do}&"             ","                      ")),
      IF(
        AND({⏎count Waiting}>0,{⏎count Waiting}<10),
        "⏎"&{⏎count Waiting}&"               ",
        IF({⏎count Waiting}>=10,"⏎"&{⏎count Waiting}&"             ",
        "                      ")),
  IF({➤count InProgress},"➤"&{➤count InProgress},BLANK())))

[Jeff_Haskin]

If you replace the “-” with a non-breaking space, you can do the same thing without a visible character.

[Jeff_Haskin]

I did this by having each task have it’s own progress field, with this formula:

IF({Status}="Done",1,0)

That field would then be hidden, it’s only purpose is the rollup.

Now just roll up that field with this formula:

AVERAGE(values)

…and boom! The total progress of all attached tasks.

You have to AVERAGE instead of SUM when working with percentages.