Help

Re: Using IF formula to check empty cells

Solved
Jump to Solution
1245 0
cancel
Showing results for 
Search instead for 
Did you mean: 
Antoine_Babia
4 - Data Explorer
4 - Data Explorer

Hi everyone,
I’m looking for a formula to check if any cells on a selection of 5 are empty. Hard to explain globally, but theorically the formula would look like this: IF (Cell 1) is empty OR (Cell 2) is empty OR (Cell 3) is empty… THEN display :white_check_mark:
How can I achieve this on Airtable?
Thanks in advance for your help.

1 Solution

Accepted Solutions
kuovonne
18 - Pluto
18 - Pluto

Welcome to the Airtable community!

You want to compare values with BLANK(), and use an OR() function.

IF(
  OR(
    Field1 = BLANK(),
    Field2 = BLANK(),
    Field3 = BLANK(),
    Field4 = BLANK(),
    Field5 = BLANK()
  ),
  "✅" 
)

If this answers your question, please mark this post as the solution. Otherwise, could you please give a bit more details and a screen capture?

See Solution in Thread

2 Replies 2
kuovonne
18 - Pluto
18 - Pluto

Welcome to the Airtable community!

You want to compare values with BLANK(), and use an OR() function.

IF(
  OR(
    Field1 = BLANK(),
    Field2 = BLANK(),
    Field3 = BLANK(),
    Field4 = BLANK(),
    Field5 = BLANK()
  ),
  "✅" 
)

If this answers your question, please mark this post as the solution. Otherwise, could you please give a bit more details and a screen capture?

An alternate approach is to use the shortcut method for checking whether or not a field has anything in it, by only including the field name. For example:

IF(Field1, ...

is equivalent to

IF(Field1 != BLANK(), ...

To invert the comparison, and see if it is blank, wrap the field name in NOT():

IF(NOT(Field1), ...

is equivalent to

IF(Field1 = BLANK(), ...

Which means the formula written above could also be written like this:

IF(
  OR(
    NOT(Field1),
    NOT(Field2),
    NOT(Field3),
    NOT(Field4),
    NOT(Field5)
  ),
  "✅" 
)

Yet another way is to invert the entire thing. Because you’re checking for any one of those fields to be blank, this will also work:

IF(NOT(AND(Field1, Field2, Field3, Field4, Field5)), "✅")

This only downside to this field-name-only shortcut is when it’s a numeric field. Airtable will read a 0 in a numeric field as false. In that case you would have to compare against BLANK() to correctly distinguish between an empty field and one that contains a 0.