Management of Birthdates

I have recorded birthdates ie day month year. The birthdates are in the past. How do I see the birthdates in the calendar for the dates ahead.

Thanks in anticipation.

Baljit

There are a couple threads that already have solutions to this problem. If you searched before posting, I’m guessing you searched for “birthdate” instead of “birthday,” which would explain why you didn’t find them. :slight_smile: I hope that something in these threads will give you what you want.

Thank you Justin Barrett,

Oh! Yes, thanks for the input, indeed ‘birthday’ has a many inputs.

Oh! but concatenate functions is a barrier for me as of now. I could not figure out what to do.

Any way is there any function in Airtable where the birthday ( or that matter any recurring date) appear indefinitely for the future years ?

So, I am yet at square one? Birthday

Thanks again Justin Barrett

Baljit

If you want a birthday for upcoming years, you need a new record for each year. Now, that doesn’t mean that you need an indefinite number of records. You could have one record for “this year” and another record for “next year”.

Assuming that the birthdate is stored in a date field in the same record, this formula will give the anniversary of the birthday in the current year.

DATETIME_PARSE(
  DAY({Birthdate}) & "-" & 
  MONTH({Birthdate}) & "-" &
  YEAR(TODAY()),
  "D-M-YYYY"
)

And this one will give it for next year:

DATETIME_PARSE(
  DAY({Birthdate}) & "-" & 
  MONTH({Birthdate}) & "-" &
  (YEAR(TODAY()) + 1),
  "D-M-YYYY"
)

If you want to calculate the “next” birthday after today, use this formula:

IF(
  DATETIME_FORMAT({Birthdate}, "MMDD") > DATETIME_FORMAT(TODAY(), "MMDD"),
  DATETIME_PARSE(
    DAY({Birthdate}) & "-" & 
    MONTH({Birthdate}) & "-" &
    YEAR(TODAY()),
    "D-M-YYYY"
  ),
  DATETIME_PARSE(
    DAY({Birthdate}) & "-" & 
    MONTH({Birthdate}) & "-" &
    (YEAR(TODAY()) + 1),
    "D-M-YYYY"
  )
)

Things get a bit more complicated if your birthdate is in a lookup field instead of the same record as the formula.


If this answers your problem, could you please mark this post as the solution?
If not, could you please give a bit more details on your use case and a screen capture?

1 Like

The formula above from @kuovonne will do the trick. If the current date is before the birthday (or other date), it will show when that date will fall in the current year; otherwise it will show where it falls next year.

FWIW, here’s an optimized version of that same formula. Because the only difference in those parsing parts is how much we’re adding to the current year, we can wrap the IF() function just around that part, returning either 0 or 1 appropriately.

DATETIME_PARSE(
	DAY({Birthdate}) & "-" & 
  	MONTH({Birthdate}) & "-" &
  	(YEAR(TODAY()) + IF(
  		DATETIME_FORMAT({Birthdate}, "MMDD") > DATETIME_FORMAT(TODAY(), "MMDD"),
  		0, 1)
  	),
  	"D-M-YYYY"
)
1 Like