Formula won't allow field to be formatted as currency

[kdburns]

I have written this formula a few different ways and in each case, I get the result but am unable to format as currency. 

Error: Your result type is not a number or a date. Formatting options are currently only available if your result type is a number or a date.

Here the two most successful attemps:

IF(
AND(
OR(
{Channel} = "Print",
{Channel} = "Digital"
),
{New | Repeat} = "New"
),
IF(
{Channel} = "Print",
"$" & VALUE("450"),
IF(
{Channel} = "Digital",
"$" & VALUE("75"),
""
)
),
""
)

IF(
AND(
OR(
{Channel} = "Print",
{Channel} = "Digital"
),
{New | Repeat} = "New"
),
IF(
{Channel} = "Print",
450,
IF(
{Channel} = "Digital",
75,
""
)
),
""
)

Any insight is greatly appreciated!!!

[Zack_S · Accepted solution]

Give this a try instead. Much simpler and I think it should accomplish the same thing for you.

IF({New | Repeat}='New', SWITCH(Channel, "Print", 450, "Digital", 75))

You also were on the right track and weren't wrong with your line of thinking. However, it complicates things. This would also work for you. I got rid of the quotations at the end of the formula as that was formatting it as text.

IF(
AND(
OR(
{Channel} = "Print",
{Channel} = "Digital"
),
{New | Repeat} = "New"
),
IF(
{Channel} = "Print",
450,
IF(
{Channel} = "Digital",
75)))

[kdburns]

THAT'S IT! 😀

I need to familiarize myself with SWITCH. I'll have more instances like this and I have a tendency to use old school formulas. Thank you!

[Zack_S]

Very simple once you wrap your head around it. Doesn't solve all problems either, but often is a good alternative to nested IF statements.