Skip to main content

I want to be able to have different icons display depending on the due date.



So far I have this, and it’s working well:



IF({Due Date} = BLANK(), BLANK(), IF({Due Date} = TODAY(), “ 🔴 ”,IF(IS_BEFORE({Due Date},TODAY()), “ ⏰ ”,IF(DATETIME_DIFF({Due Date}, TODAY(), ‘days’) < 6, " ⚠ ))))



I want to add the condition that if my “To-Do” field is checked (it’s a checkmark field), then nothing is displayed. I tried this for that command:



IF({Due Date} = BLANK(), BLANK(), IF({Due Date} = TODAY(), “ 🔴 ”,IF(IS_BEFORE({Due Date},TODAY()), “ ⏰ ”,IF(DATETIME_DIFF({Due Date}, TODAY(), ‘days’) < 6, “ ⚠ ”,IF({To-Do} != BLANK(), BLANK())))))



It doesn’t return an error but it also doesn’t make the field blank when To-Do is checked.



Any suggestions?

Hi @Brenda_Carey - I think this will do it for you:



IF(


  AND({Due Date}, NOT({To-Do})), 


  IF(


    {Due Date} = TODAY(), 


    '🔴',


    IF(


      IS_BEFORE({Due Date},TODAY()), 


      '⏰',


      IF(


        DATETIME_DIFF({Due Date}, TODAY(), 'days') < 6, 


        '⚠️'


      )


    )


  )


)


The first part of the IF statement is saying “if there is a due date AND the to-do is not checked, then continue”





JB

Hi @Brenda_Carey - I think this will do it for you:



IF(


  AND({Due Date}, NOT({To-Do})), 


  IF(


    {Due Date} = TODAY(), 


    '🔴',


    IF(


      IS_BEFORE({Due Date},TODAY()), 


      '⏰',


      IF(


        DATETIME_DIFF({Due Date}, TODAY(), 'days') < 6, 


        '⚠️'


      )


    )


  )


)


The first part of the IF statement is saying “if there is a due date AND the to-do is not checked, then continue”





JB


Perfect!! Thank you so much. I’m still new to making formulas.

Reply


Terms & Conditions