Feature Request: Checklist Field Type

Hey @Brian_LWA,

This still won’t be as nice as Trello’s checklist fields, but here’s how I make this experience a bit nicer in Airtable. I have my “subtasks” in a long text field called Notes, which you’ll see referenced in the formulas below – replace with your long text field name.

1. Create a formula field Open Subtasks with this formula

(LEN(Notes) - LEN(SUBSTITUTE(Notes, "[ ]", ""))) / 3

2. Create a formula field Completed Subtasks with this formula

(LEN(Notes) - LEN(SUBSTITUTE(Notes, "[x]", ""))) / 3

3. Create a formula field Total Subtasks with this formula

{Open Subtasks} + {Completed Subtasks}

4. Create a formula field Subtasks % Completed with this formula

IF({Total Subtasks}, {Completed Subtasks} / {Total Subtasks})

5. Create a formula field Subtasks with this formula

IF(
  {Total Subtasks},
  {Completed Subtasks} & '/' & {Total Subtasks} & ' subtasks '
) &
IF(
  {Total Subtasks},
  IF(
    {Subtasks % Completed} < 1,
    '⭕️',
    '✅'
  )
)

6. Hide all but this final Subtasks field

Result

Doesn’t help with seeing the actual text of your subtasks – I don’t have a good solution for that in Airtable. But it does at least give you that visual prompt of whether or not you need to expand and look at those subtasks. There’s also a nice little perk that these formulas don’t care if all your subtasks are grouped together in the Notes field – it will find them anywhere; so you can freely put inline tasks as you think of them, interspersed as you please between your notes.

:slightly_smiling_face:

Very helpful @Jeremy_Oglesby. I’ll definitely add this in for now as a temporary solution but I think the checklist feature that Trello and SmartSuite have is a MUST as that’s such a highly used feature for productivity. Thank you for writing all this out!