Academic Year Tags - September Start Date

Hey Mackenzie! Yes, this is definitely possible to adjust 😊 It just sounds like your current formula/automation logic may be using the calendar year rather than accounting for the September start of your academic year. If you’re able to share the formula you’re currently using, along with screenshots of the relevant automation steps, I’d be happy to take a look and help troubleshoot your specific setup! 

In general, you’ll want the logic to check the trainee’s start date and use September as the cutoff — so for example, anyone starting September through December would be assigned to the academic year beginning in that same calendar year, while anyone starting January through August would belong to the academic year that began the previous calendar year — but once I can see how you’re currently generating the tag, I’m happy to help with the exact adjustment! 

Hm, assuming your academic year is 1 Aug to 31 July, then perhaps you could try using this formula with your automation?

IF(
  {Start Date},
  IF(
    MONTH({Start Date}) >= 8,
    YEAR({Start Date}) & " - " & (YEAR({Start Date}) + 1),
    (YEAR({Start Date}) - 1) & " - " & YEAR({Start Date})
  )
)

Your symptom (September → 2025 - 2026 instead of 2026 - 2027) usually means the formula treats September as the end of the previous academic year. For a year that starts in September, use month 9 as the cutoff:

IF(
  {Start Date},
  IF(
    MONTH({Start Date}) >= 9,
    YEAR({Start Date}) & " - " & (YEAR({Start Date}) + 1),
    (YEAR({Start Date}) - 1) & " - " & YEAR({Start Date})
  )
)

Quick check: Sep 15, 2026 → 2026 - 2027; Aug 15, 2026 → 2025 - 2026; Jan 10, 2027 → 2026 - 2027.

If you currently see the wrong tag on September dates, search for a formula that looks like this (branches swapped) and replace it:

IF(MONTH({Start Date}) >= 9,
  (YEAR({Start Date}) - 1) & " - " & YEAR({Start Date}),
  YEAR({Start Date}) & " - " & (YEAR({Start Date}) + 1)
)

If your academic year actually starts August 1, change >= 9 to >= 8 instead. Put this in a Formula field (or the same expression in the automation that writes the tag), then re-run or re-save a few sample September records to confirm.

Disclosure: I'm on the Duaer team; this was drafted with AI help and checked against Airtable's support docs.

Thanks for actual possibilities !  

Below is the formula we currently use in the automation. 

IF(

  OR(

    MONTH({Position_Start_Date}) > 8, 

    AND(

      MONTH({Position_Start_Date}) = 8, 

      DAY({Position_Start_Date}) > 15

    )

  ), 

  YEAR({Position_Start_Date}) & '-' & RIGHT((YEAR({Position_Start_Date}) + 1)&'', 2) & ' Academic Year', 

  IF(

    MONTH({Position_Start_Date}) > 7, 

    '', 

    YEAR({Position_Start_Date}) - 1 & '-' & RIGHT(YEAR({Position_Start_Date})&'', 2) & ' Academic Year'

  )

Hey ​@mmlachance, thanks for sharing the formula! I tested it using a few different start dates, and the formula itself does appear to be handling September correctly. For example, 9/1/2026 returns 2026-27 Academic Year as expected.

I also noticed one other thing in the current logic: August 1–15 will return a blank value. Right now, the formula is doing this:

• January–July = previous year/current year
• August 1–15 = blank
• August 16–December = current year/next year

If that blank period is intentional, then your formula should be behaving as expected! But if you want all August dates to be assigned an academic year, that section of the formula would need to be adjusted. For example, if you want August 1–15 to fall into the previous academic year, you could use this version instead:

IF(
  OR(
    MONTH({Position_Start_Date}) > 8,
    AND(
      MONTH({Position_Start_Date}) = 8,
      DAY({Position_Start_Date}) > 15
    )
  ),
  YEAR({Position_Start_Date}) & '-' &
  RIGHT((YEAR({Position_Start_Date}) + 1) & '', 2) &
  ' Academic Year',
  (YEAR({Position_Start_Date}) - 1) & '-' &
  RIGHT(YEAR({Position_Start_Date}) & '', 2) &
  ' Academic Year'
)

I tested both versions side by side below. Your original formula is in Academic Year (mmlachance), and my revised version is in Academic Year (bredah): 

Since your original formula is already returning the expected result for September, I’d still take a look at the automation step that writes the Academic Year value for one of the affected trainees. If you want to share a screenshot of that step, I’m happy to take another look! 😊