Skip to main content
Question

Help with formula to bring different fields together depending on conditions

  • June 30, 2026
  • 2 replies
  • 0 views
H
Forum|alt.badge.img+11

Hi, 

Wondered if anyone could help with this…

I have the following fields

Title, Sub Title, Series Title and Series Order

Then I have a full title field where I want to bring those together depending on which of those is filled in. 

So, if there’s a Sub Title, I want the Full title to show {Title}: {Sub Title}. If there is a series title then I want it to show {Title}: {Series Title} {Series Order} (as an aside, if I could get the series order in brackets that would be amazing, but I suspect impossible because brackets are part of the formula). And if neither Sub Title nor Series Title have an entry then I just want the {Title}. I don’t think there’ll ever be a case where we have a series title and a sub title so I’m not worried about that for now. 

At the moment I have:

IF(

  {Series Title}, {Title} & ": " & {Series Title} & " " & {Series Order}, 

    IF(

      {Sub Title}, {Title} & ": " & {Sub Title},

      IF({Series Title} = BLANK(), AND({Sub Title} = BLANK(), {Title}))

      ))

 

And it works for the cases where there is a Sub Title or Series Title, but everything else just returns the word True. What have I done wrong? 

Thank you

2 replies

H
Forum|alt.badge.img+11
  • HannahS
  • Author
  • Known Participant
  • June 30, 2026

Ah, I’ve fixed it:

IF(

{Series Title},

{Title} & ": " & {Series Title} & " " & {Series Order},

IF(

{Sub Title},

{Title} & ": " & {Sub Title},

{Title}

)

)

 

If you do know of a way to include brackets in the punctuation of the result I’d love to hear it...the first entry currently returns, for instance:

GIRL ON FIRE: Forgotten Gods 1

and I’d love it to be

GIRL ON FIRE: Forgotten Gods (1)

But not a major issue if that can’t be done. 

 

TheTimeSavingCo
Forum|alt.badge.img+32

Does this look right?  If so I’ve set it up here for you to check out!

And here's the formula:

IF(
  {Series Title},
  {Title} & 
  ": " & 
  {Series Title} & 
  IF(
    {Series Order},
    " (" & {Series Order} & ")"
  ),
  IF(
    {Sub Title},
    {Title} & ": " & {Sub Title},
    {Title}
  )
)

 

Adam, Airtable Consultant - thetimesaving.company
Terms & ConditionsAccessibility statement