Skip to main content
Question

How has airtable still not fixed basic time maths??

  • April 7, 2026
  • 6 replies
  • 44 views
R
Forum|alt.badge.img+5

I sometimes wonder why I still pay airtable money. For an application that claims to be good for time planning it’s mad it still doesn’t seem to be able to do time and date maths properly. 

I am in UK (so GMT/BST) - I want to have a date field and a separate time field, and to be able to combine these two into a calculated dateTime

nothing I have tried seems to work reliably for this without jumping the date back to UTC 

Has anyone found a solution for what should be a trivial task?

Thanks

 

Richard

6 replies

anmolgupta
Forum|alt.badge.img+3
  • anmolgupta
  • Participating Frequently
  • April 7, 2026

Can you share how exactly you are storing Date and Time as separate fields? A formula field can be written on basis of it.

Anmol Gupta | Founder PhotonMan.ai
R
Forum|alt.badge.img+5
  • Richard_Willia1
  • Author
  • Known Participant
  • April 7, 2026

Thanks for coming back to me 

I have a date time field, and a separate text field for just time. The formula needs to take the date from the date time and add the time (london) to it 

one of the complicating factors is also handling summer time 

 

Any ideas appreciated!!

DisraeliGears01
Forum|alt.badge.img+21

Can you try 

DATETIME_PARSE(
    CONCATENATE(
        DATESTR({TestDate}) & " ",
        {Time} & " ",
        DATETIME_FORMAT(
            SET_TIMEZONE(
              {TestDate},
              'Europe/London'
            ),
            'Z'
        )
    ),
    "YYYY-MM-DD H:mma Z"
)

Replacing {TestDate} and {Time} with your field names... Also make sure in the formula field settings to select London time zone. 

I figured this was doable with Parse, but tbh all credit to ​@kuovonne who solved it in this thread from awhile back.

coderkid
Forum|alt.badge.img+5
  • coderkid
  • Inspiring
  • April 8, 2026

I am not saying ​@DisraeliGears01’s code wrong. But using CONCATENATE function and operators (&) doesn’t that much make sense to my computer science educated brain.. So I changed his code alittle bit to make it more efficient :
 

DATETIME_PARSE(
  DATETIME_FORMAT({DateField}, 'YYYY-MM-DD') &
  ' ' &
  {TimeField} &
  ' ' &
  DATETIME_FORMAT(SET_TIMEZONE({DateField}, 'Europe/London'), 'Z'),
  'YYYY-MM-DD H:mma Z'
)

 

R
Forum|alt.badge.img+5
  • Richard_Willia1
  • Author
  • Known Participant
  • April 8, 2026

Oh wow that works - thanks!! I am a bit confused about how it works but that is amazing. Thanks!

coderkid
Forum|alt.badge.img+5
  • coderkid
  • Inspiring
  • April 8, 2026

​@Richard_Willia1 I can explain it pieces :

DATETIME_FORMAT({DateField}, 'YYYY-MM-DD')

Turns {DateField} into a clean text date like: "2026-04-08"

' ' & {TimeField} & ' ' &

We add the {TimeField} with spaces around; adds something like “ 10:15 “, now it turns to something like “2026-04-08 10:15 "

DATETIME_FORMAT(SET_TIMEZONE({DateField}, 'Europe/London'), 'Z')

Then we get the timezone offset for London; whether "+0100" (BST) or "+0000" (GMT), and concatenate it to the date/time string. Now it turns to something like “2026-04-08 10:15 +0100"

DATETIME_PARSE(..., 'YYYY-MM-DD H:mma Z')

And then we convert that string back into a real Date/Time

Terms & ConditionsAccessibility statement